nixpkgs/pkgs/applications/networking/cluster/stern/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

{ stdenv, lib, buildPackages, buildGoPackage, fetchFromGitHub, installShellFiles }:

let isCrossBuild = stdenv.hostPlatform != stdenv.buildPlatform; in

buildGoPackage rec {
  pname = "stern";
  version = "1.11.0";

  goPackagePath = "github.com/wercker/stern";

  src = fetchFromGitHub {
    owner = "wercker";
    repo = "stern";
    rev = version;
    sha256 = "0xndlq0ks8flzx6rdd4lnkxpkbvdy9sj1jwys5yj7p989ls8by3n";
  };

  deleteVendor = true;
  goDeps = ./deps.nix;

  nativeBuildInputs = [ installShellFiles ];

  postInstall =
    let stern = if isCrossBuild then buildPackages.stern else "$out"; in
    ''
      for shell in bash zsh; do
        ${stern}/bin/stern --completion $shell > stern.$shell
        installShellCompletion stern.$shell
      done
    '';

  meta = with lib; {
    description      = "Multi pod and container log tailing for Kubernetes";
    homepage         = "https://github.com/wercker/stern";
    license          = licenses.asl20;
    maintainers      = with maintainers; [ mbode ];
    platforms        = platforms.unix;
  };
}