blob: ee84e707102328fea69af10218b1a61d98aa2128 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
{ pkgs, config, lib, ... }:
with lib;
let
cfg = config.programs.vscode.haskell;
defaultHieNixExe = hie-nix.hies + "/bin/hie-wrapper";
defaultHieNixExeText =
literalExample ''"''${pkgs.hie-nix.hies}/bin/hie-wrapper"'';
hie-nix = pkgs.hie-nix or (abort ''
vscode.haskell: pkgs.hie-nix missing. Please add an overlay such as:
${exampleOverlay}
'');
exampleOverlay = ''
nixpkgs.overlays = [
(self: super: { hie-nix = import ~/src/hie-nix {}; })
]
'';
in {
options.programs.vscode.haskell = {
enable = mkEnableOption "Haskell integration for Visual Studio Code";
hie.enable = mkOption {
type = types.bool;
default = true;
description = "Whether to enable Haskell IDE engine integration.";
};
hie.executablePath = mkOption {
type = types.path;
default = defaultHieNixExe;
defaultText = defaultHieNixExeText;
description = ''
The path to the Haskell IDE Engine executable.
</para><para>
Because hie-nix is not packaged in Nixpkgs, you need to add it as an
overlay or set this option. Example overlay configuration:
<programlisting language="nix">${exampleOverlay}</programlisting>
'';
example = literalExample ''
(import ~/src/haskell-ide-engine {}).hies + "/bin/hie-wrapper";
'';
};
};
config = mkIf cfg.enable {
programs.vscode.userSettings = mkIf cfg.hie.enable {
"languageServerHaskell.enableHIE" = true;
"languageServerHaskell.hieExecutablePath" = cfg.hie.executablePath;
};
programs.vscode.extensions =
[ pkgs.vscode-extensions.justusadam.language-haskell ]
++ lib.optional cfg.hie.enable
pkgs.vscode-extensions.alanz.vscode-hie-server;
};
}
|
