1 files changed, 87 insertions, 26 deletions

diff --git a/modules/services/emacs.nix b/modules/services/emacs.nix
index c027626253d..7b91bcc2923 100644
--- a/modules/services/emacs.nix
+++ b/modules/services/emacs.nix
@@ -7,6 +7,8 @@ let
   cfg = config.services.emacs;
   emacsCfg = config.programs.emacs;
   emacsBinPath = "${emacsCfg.finalPackage}/bin";
+  emacsVersion = getVersion emacsCfg.finalPackage;
+
   # Adapted from upstream emacs.desktop
   clientDesktopItem = pkgs.makeDesktopItem rec {
     name = "emacsclient";
@@ -27,9 +29,26 @@ let
     '';
   };
 
+  # Match the default socket path for the Emacs version so emacsclient continues
+  # to work without wrapping it. It might be worthwhile to allow customizing the
+  # socket path, but we would want to wrap emacsclient in the user profile to
+  # connect to the alternative socket by default for Emacs 26, and set
+  # EMACS_SOCKET_NAME for Emacs 27.
+  #
+  # As systemd doesn't perform variable expansion for the ListenStream param, we
+  # would also have to solve the problem of matching the shell path to the path
+  # used in the socket unit, which would likely involve templating. It seems of
+  # little value for the most common use case of one Emacs daemon per user
+  # session.
+  socketPath = if versionAtLeast emacsVersion "27" then
+    "%t/emacs/server"
+  else
+    "%T/emacs%U/server";
+
 in {
   options.services.emacs = {
     enable = mkEnableOption "the Emacs daemon";
+
     client = {
       enable = mkEnableOption "generation of Emacs client desktop file";
       arguments = mkOption {
@@ -40,36 +59,78 @@ in {
         '';
       };
     };
+
+    # Attrset for forward-compatibility; there may be a need to customize the
+    # socket path, though allowing for such is not easy to do as systemd socket
+    # units don't perform variable expansion for 'ListenStream'.
+    socketActivation = {
+      enable = mkEnableOption "systemd socket activation for the Emacs service";
+    };
   };
 
-  config = mkIf cfg.enable {
-    assertions = [{
-      assertion = emacsCfg.enable;
-      message = "The Emacs service module requires"
-        + " 'programs.emacs.enable = true'.";
-    }];
-
-    systemd.user.services.emacs = {
-      Unit = {
-        Description = "Emacs: the extensible, self-documenting text editor";
-        Documentation =
-          "info:emacs man:emacs(1) https://gnu.org/software/emacs/";
-
-        # Avoid killing the Emacs session, which may be full of
-        # unsaved buffers.
-        X-RestartIfChanged = false;
-      };
+  config = mkIf cfg.enable (mkMerge [
+    {
+      assertions = [
+        {
+          assertion = emacsCfg.enable;
+          message = "The Emacs service module requires"
+            + " 'programs.emacs.enable = true'.";
+        }
+        {
+          assertion = cfg.socketActivation.enable
+            -> versionAtLeast emacsVersion "26";
+          message = "Socket activation requires Emacs 26 or newer.";
+        }
+      ];
+
+      systemd.user.services.emacs = {
+        Unit = {
+          Description = "Emacs: the extensible, self-documenting text editor";
+          Documentation =
+            "info:emacs man:emacs(1) https://gnu.org/software/emacs/";
 
-      Service = {
-        ExecStart =
-          "${pkgs.runtimeShell} -l -c 'exec ${emacsBinPath}/emacs --fg-daemon'";
-        ExecStop = "${emacsBinPath}/emacsclient --eval '(kill-emacs)'";
-        Restart = "on-failure";
+          # Avoid killing the Emacs session, which may be full of
+          # unsaved buffers.
+          X-RestartIfChanged = false;
+        };
+
+        Service = {
+          ExecStart = "${emacsBinPath}/emacs --fg-daemon${
+            # In case the user sets 'server-directory' or 'server-name' in
+            # their Emacs config, we want to specify the socket path explicitly
+            # so launching 'emacs.service' manually doesn't break emacsclient
+            # when using socket activation.
+              optionalString cfg.socketActivation.enable ''="${socketPath}"''
+            }";
+          # We use '(kill-emacs 0)' to avoid exiting with a failure code, which
+          # would restart the service immediately.
+          ExecStop = "${emacsBinPath}/emacsclient --eval '(kill-emacs 0)'";
+          Restart = "on-failure";
+        };
+      } // optionalAttrs (!cfg.socketActivation.enable) {
+        Install = { WantedBy = [ "default.target" ]; };
       };
 
-      Install = { WantedBy = [ "default.target" ]; };
-    };
+      home.packages = optional cfg.client.enable clientDesktopItem;
+    }
 
-    home.packages = optional cfg.client.enable clientDesktopItem;
-  };
+    (mkIf cfg.socketActivation.enable {
+      systemd.user.sockets.emacs = {
+        Unit = {
+          Description = "Emacs: the extensible, self-documenting text editor";
+          Documentation =
+            "info:emacs man:emacs(1) https://gnu.org/software/emacs/";
+        };
+
+        Socket = {
+          ListenStream = socketPath;
+          FileDescriptorName = "server";
+          SocketMode = "0600";
+          DirectoryMode = "0700";
+        };
+
+        Install = { WantedBy = [ "sockets.target" ]; };
+      };
+    })
+  ]);
 }