1 files changed, 48 insertions, 0 deletions
diff --git a/home-manager/modules/programs/beets.nix b/home-manager/modules/programs/beets.nix
new file mode 100644
index 00000000000..152bfd304a4
--- /dev/null
+++ b/home-manager/modules/programs/beets.nix
@@ -0,0 +1,48 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.programs.beets;
+
+in
+
+{
+  meta.maintainers = [ maintainers.rycee ];
+
+  options = {
+    programs.beets = {
+      enable = mkOption {
+        type = types.bool;
+        default =
+          if versionAtLeast config.home.stateVersion "19.03"
+          then false
+          else cfg.settings != {};
+        defaultText = "false";
+        description = ''
+          Whether to enable the beets music library manager. This
+          defaults to <literal>false</literal> for state
+          version ≥ 19.03. For earlier versions beets is enabled if
+          <option>programs.beets.settings</option> is non-empty.
+        '';
+      };
+
+      settings = mkOption {
+        type = types.attrs;
+        default = {};
+        description = ''
+          Configuration written to
+          <filename>~/.config/beets/config.yaml</filename>
+        '';
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = [ pkgs.beets ];
+
+    xdg.configFile."beets/config.yaml".text =
+        builtins.toJSON config.programs.beets.settings;
+  };
+}