Add 'nixpkgs/' from commit '2436c27541b2f52deea3a4c1691216a02152e729'

git-subtree-dir: nixpkgs
git-subtree-mainline: 1148b1d122bc03e9a3665856c9b7bb96bd4e3994
git-subtree-split: 2436c27541b2f52deea3a4c1691216a02152e729

1 files changed, 79 insertions, 0 deletions

diff --git a/nixpkgs/pkgs/development/python-modules/pelican/default.nix b/nixpkgs/pkgs/development/python-modules/pelican/default.nix
new file mode 100644
index 00000000000..2dcc3e5b873
--- /dev/null
+++ b/nixpkgs/pkgs/development/python-modules/pelican/default.nix
@@ -0,0 +1,79 @@
+{ stdenv, buildPythonPackage, fetchFromGitHub
+, glibcLocales, git
+, mock, nose, markdown, lxml, typogrify
+, jinja2, pygments, docutils, pytz, unidecode, six, dateutil, feedgenerator
+, blinker, pillow, beautifulsoup4, markupsafe }:
+
+buildPythonPackage rec {
+  pname = "pelican";
+  version = "4.1.0";
+
+  src = fetchFromGitHub {
+    owner = "getpelican";
+    repo = "pelican";
+    rev = version;
+    sha256 = "1ww3kc5bzp5q7b23n2vmzqch1z06l7vrscn0h96cscvk45sxc7yz";
+    # Remove unicode file names which leads to different checksums on HFS+
+    # vs. other filesystems because of unicode normalisation.
+    extraPostFetch = ''
+      rm -r $out/pelican/tests/output/custom_locale/posts
+    '';
+  };
+
+  doCheck = true;
+
+  # Exclude custom locale test, which files were removed above to fix the source checksum
+  checkPhase = ''
+    nosetests -sv --exclude=test_custom_locale_generation_works pelican
+  '';
+
+  buildInputs = [
+    glibcLocales
+    # Note: Pelican has to adapt to a changed CLI of pandoc before enabling this
+    # again. Compare https://github.com/getpelican/pelican/pull/2252.
+    # Version 4.1.0 is incompatible with our current pandoc version.
+    # pandoc
+    git
+    mock
+    markdown
+    typogrify
+  ];
+
+  propagatedBuildInputs = [
+    jinja2 pygments docutils pytz unidecode six dateutil feedgenerator
+    blinker pillow beautifulsoup4 markupsafe lxml
+  ];
+
+  checkInputs = [
+    nose
+  ];
+
+  postPatch= ''
+    substituteInPlace pelican/tests/test_pelican.py \
+      --replace "'git'" "'${git}/bin/git'"
+
+    # Markdown-3.1 changed footnote separator to colon
+    # https://github.com/getpelican/pelican/issues/2493#issuecomment-491723744
+    sed -i '/test_article_with_footnote/i\
+        @unittest.skip("")' pelican/tests/test_readers.py
+  '';
+
+  LC_ALL="en_US.UTF-8";
+
+
+  # We only want to patch shebangs in /bin, and not those
+  # of the project scripts that are created by Pelican.
+  # See https://github.com/NixOS/nixpkgs/issues/30116
+  dontPatchShebangs = true;
+
+  postFixup = ''
+    patchShebangs $out/bin
+  '';
+
+  meta = with stdenv.lib; {
+    description = "A tool to generate a static blog from reStructuredText or Markdown input files";
+    homepage = http://getpelican.com/;
+    license = licenses.agpl3;
+    maintainers = with maintainers; [ offline prikhi ];
+  };
+}