Add 'home-manager/' from commit '8bddc1adab0f7a51476f819fa2197353e8e1d136'

git-subtree-dir: home-manager
git-subtree-mainline: 919d4e75699aa4ba456fd2d3d416a0522c9c7294
git-subtree-split: 8bddc1adab0f7a51476f819fa2197353e8e1d136

1 files changed, 71 insertions, 0 deletions

diff --git a/home-manager/nix-darwin/default.nix b/home-manager/nix-darwin/default.nix
new file mode 100644
index 00000000000..1482c7bb245
--- /dev/null
+++ b/home-manager/nix-darwin/default.nix
@@ -0,0 +1,71 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.home-manager;
+
+  hmModule = types.submodule ({name, ...}: {
+    imports = import ../modules/modules.nix { inherit lib pkgs; };
+
+    config = {
+      submoduleSupport.enable = true;
+      submoduleSupport.externalPackageInstall = cfg.useUserPackages;
+
+      home.username = config.users.users.${name}.name;
+      home.homeDirectory = config.users.users.${name}.home;
+    };
+  });
+
+in
+
+{
+  options = {
+    home-manager = {
+      useUserPackages = mkEnableOption ''
+        installation of user packages through the
+        <option>users.users.‹name?›.packages</option> option.
+      '';
+
+      users = mkOption {
+        type = types.attrsOf hmModule;
+        default = {};
+        description = ''
+          Per-user Home Manager configuration.
+        '';
+      };
+    };
+  };
+
+  config = mkIf (cfg.users != {}) {
+    warnings =
+      flatten (flip mapAttrsToList cfg.users (user: config:
+        flip map config.warnings (warning:
+          "${user} profile: ${warning}"
+        )
+      ));
+
+    assertions =
+      flatten (flip mapAttrsToList cfg.users (user: config:
+        flip map config.assertions (assertion:
+          {
+            inherit (assertion) assertion;
+            message = "${user} profile: ${assertion.message}";
+          }
+        )
+      ));
+
+    users.users = mkIf cfg.useUserPackages (
+      mapAttrs (username: usercfg: {
+        packages = usercfg.home.packages;
+      }) cfg.users
+    );
+
+    system.activationScripts.postActivation.text =
+      concatStringsSep "\n" (mapAttrsToList (username: usercfg: ''
+        echo Activating home-manager configuration for ${username}
+        sudo -u ${username} -i ${usercfg.home.activationPackage}/activate
+      '') cfg.users);
+  };
+}