Add 'home-manager/' from commit '8bddc1adab0f7a51476f819fa2197353e8e1d136'

git-subtree-dir: home-manager
git-subtree-mainline: 919d4e75699aa4ba456fd2d3d416a0522c9c7294
git-subtree-split: 8bddc1adab0f7a51476f819fa2197353e8e1d136

1 files changed, 58 insertions, 0 deletions

diff --git a/home-manager/modules/programs/vscode.nix b/home-manager/modules/programs/vscode.nix
new file mode 100644
index 00000000000..3a82816f588
--- /dev/null
+++ b/home-manager/modules/programs/vscode.nix
@@ -0,0 +1,58 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.programs.vscode;
+
+  configFilePath =
+    if pkgs.stdenv.hostPlatform.isDarwin then
+      "Library/Application Support/Code/User/settings.json"
+    else
+      "${config.xdg.configHome}/Code/User/settings.json";
+
+in
+
+{
+  options = {
+    programs.vscode = {
+      enable = mkEnableOption "Visual Studio Code";
+
+      userSettings = mkOption {
+        type = types.attrs;
+        default = {};
+        example = literalExample ''
+          {
+            "update.channel" = "none";
+            "[nix]"."editor.tabSize" = 2;
+          }
+        '';
+        description = ''
+          Configuration written to Visual Studio Code's
+          <filename>settings.json</filename>.
+        '';
+      };
+
+      extensions = mkOption {
+        type = types.listOf types.package;
+        default = [];
+        example = literalExample "[ pkgs.vscode-extensions.bbenoist.Nix ]";
+        description = ''
+          The extensions Visual Studio Code should be started with.
+          These will override but not delete manually installed ones.
+        '';
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = [
+      (pkgs.vscode-with-extensions.override {
+        vscodeExtensions = cfg.extensions;
+      })
+    ];
+
+    home.file."${configFilePath}".text = builtins.toJSON cfg.userSettings;
+  };
+}