Add 'home-manager/' from commit '8bddc1adab0f7a51476f819fa2197353e8e1d136'

git-subtree-dir: home-manager
git-subtree-mainline: 919d4e75699aa4ba456fd2d3d416a0522c9c7294
git-subtree-split: 8bddc1adab0f7a51476f819fa2197353e8e1d136

1 files changed, 54 insertions, 0 deletions

diff --git a/home-manager/modules/programs/eclipse.nix b/home-manager/modules/programs/eclipse.nix
new file mode 100644
index 00000000000..4a432c9fe1a
--- /dev/null
+++ b/home-manager/modules/programs/eclipse.nix
@@ -0,0 +1,54 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.programs.eclipse;
+
+in
+
+{
+  meta.maintainers = [ maintainers.rycee ];
+
+  options = {
+    programs.eclipse = {
+      enable = mkEnableOption "Eclipse";
+
+      enableLombok = mkOption {
+        type = types.bool;
+        default = false;
+        example = true;
+        description = ''
+          Whether to enable the Lombok Java Agent in Eclipse. This is
+          necessary to use the Lombok class annotations.
+        '';
+      };
+
+      jvmArgs = mkOption {
+        type = types.listOf types.str;
+        default = [];
+        description = "JVM arguments to use for the Eclipse process.";
+      };
+
+      plugins = mkOption {
+        type = types.listOf types.package;
+        default = [];
+        description = "Plugins that should be added to Eclipse.";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = [
+      (pkgs.eclipses.eclipseWithPlugins {
+        eclipse = pkgs.eclipses.eclipse-platform;
+        jvmArgs =
+          cfg.jvmArgs
+          ++ optional cfg.enableLombok
+              "-javaagent:${pkgs.lombok}/share/java/lombok.jar";
+        plugins = cfg.plugins;
+      })
+    ];
+  };
+}