Add 'home-manager/' from commit '8bddc1adab0f7a51476f819fa2197353e8e1d136'

git-subtree-dir: home-manager
git-subtree-mainline: 919d4e75699aa4ba456fd2d3d416a0522c9c7294
git-subtree-split: 8bddc1adab0f7a51476f819fa2197353e8e1d136

1 files changed, 56 insertions, 0 deletions

diff --git a/home-manager/modules/default.nix b/home-manager/modules/default.nix
new file mode 100644
index 00000000000..9f6404ff9cc
--- /dev/null
+++ b/home-manager/modules/default.nix
@@ -0,0 +1,56 @@
+{ configuration
+, pkgs
+, lib ? pkgs.stdenv.lib
+
+  # Whether to check that each option has a matching declaration.
+, check ? true
+}:
+
+with lib;
+
+let
+
+  collectFailed = cfg:
+    map (x: x.message) (filter (x: !x.assertion) cfg.assertions);
+
+  showWarnings = res:
+    let
+      f = w: x: builtins.trace "warning: ${w}" x;
+    in
+      fold f res res.config.warnings;
+
+  rawModule = lib.evalModules {
+    modules =
+      [ configuration ]
+      ++ (import ./modules.nix { inherit check lib pkgs; });
+    specialArgs = {
+      modulesPath = builtins.toString ./.;
+    };
+  };
+
+  module = showWarnings (
+    let
+      failed = collectFailed rawModule.config;
+      failedStr = concatStringsSep "\n" (map (x: "- ${x}") failed);
+    in
+      if failed == []
+      then rawModule
+      else throw "\nFailed assertions:\n${failedStr}"
+  );
+
+in
+
+{
+  inherit (module) options config;
+
+  activationPackage = module.config.home.activationPackage;
+
+  # For backwards compatibility. Please use activationPackage instead.
+  activation-script = module.config.home.activationPackage;
+
+  newsDisplay = rawModule.config.news.display;
+  newsEntries =
+    sort (a: b: a.time > b.time) (
+      filter (a: a.condition) rawModule.config.news.entries
+    );
+}