firefox: add module

2 files changed, 56 insertions, 0 deletions

diff --git a/modules/default.nix b/modules/default.nix
index 6f42de2f4bc..340cfefebac 100644
--- a/modules/default.nix
+++ b/modules/default.nix
@@ -11,6 +11,7 @@ let
     ./programs/beets.nix
     ./programs/eclipse.nix
     ./programs/emacs.nix
+    ./programs/firefox.nix
     ./programs/git.nix
     ./programs/gnome-terminal.nix
     ./programs/lesspipe.nix
diff --git a/modules/programs/firefox.nix b/modules/programs/firefox.nix
new file mode 100644
index 00000000000..befacec24b5
--- /dev/null
+++ b/modules/programs/firefox.nix
@@ -0,0 +1,55 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.programs.firefox;
+
+in
+
+{
+  options = {
+    programs.firefox = {
+      enable = mkEnableOption "Firefox";
+
+      package = mkOption {
+        type = types.package;
+        default = pkgs.firefox-unwrapped;
+        defaultText = "pkgs.firefox-unwrapped";
+        description = "The unwrapped Firefox package to use.";
+      };
+
+      enableAdobeFlash = mkOption {
+        type = types.bool;
+        default = false;
+        description = "Whether to enable the unfree Adobe Flash plugin.";
+      };
+
+      enableGoogleTalk = mkOption {
+        type = types.bool;
+        default = false;
+        description = "Whether to enable the unfree Google Talk plugin.";
+      };
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages =
+      let
+        # A bit of hackery to force a config into the wrapper.
+        browserName = cfg.package.browserName
+          or (builtins.parseDrvName cfg.package.name).name;
+
+        fcfg = setAttrByPath [browserName] {
+          enableAdobeFlash = cfg.enableAdobeFlash;
+          enableGoogleTalkPlugin = cfg.enableGoogleTalk;
+        };
+
+        wrapper = pkgs.wrapFirefox.override {
+          config = fcfg;
+        };
+      in
+        [ (wrapper cfg.package { }) ];
+  };
+}