1 files changed, 107 insertions, 0 deletions
diff --git a/home-manager/nix-darwin/default.nix b/home-manager/nix-darwin/default.nix
new file mode 100644
index 00000000000..12d02174332
--- /dev/null
+++ b/home-manager/nix-darwin/default.nix
@@ -0,0 +1,107 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.home-manager;
+
+  extendedLib = import ../modules/lib/stdlib-extended.nix pkgs.lib;
+
+  hmModule = types.submoduleWith {
+    specialArgs = { lib = extendedLib; };
+    modules = [
+      ({ name, ... }: {
+        imports = import ../modules/modules.nix {
+          inherit pkgs;
+          lib = extendedLib;
+          useNixpkgsModule = !cfg.useGlobalPkgs;
+        };
+
+        config = {
+          submoduleSupport.enable = true;
+          submoduleSupport.externalPackageInstall = cfg.useUserPackages;
+
+          home.username = config.users.users.${name}.name;
+          home.homeDirectory = config.users.users.${name}.home;
+        };
+      })
+    ];
+  };
+
+in
+
+{
+  options = {
+    home-manager = {
+      useUserPackages = mkEnableOption ''
+        installation of user packages through the
+        <option>users.users.‹name?›.packages</option> option.
+      '';
+
+      useGlobalPkgs = mkEnableOption ''
+        using the system configuration's <literal>pkgs</literal>
+        argument in Home Manager. This disables the Home Manager
+        options <option>nixpkgs.*</option>
+      '';
+
+      backupFileExtension = mkOption {
+        type = types.nullOr types.str;
+        default = null;
+        example = "backup";
+        description = ''
+          On activation move existing files by appending the given
+          file extension rather than exiting with an error.
+        '';
+      };
+
+      verbose = mkEnableOption "verbose output on activation";
+
+      users = mkOption {
+        type = types.attrsOf hmModule;
+        default = {};
+        description = ''
+          Per-user Home Manager configuration.
+        '';
+      };
+    };
+  };
+
+  config = mkIf (cfg.users != {}) {
+    warnings =
+      flatten (flip mapAttrsToList cfg.users (user: config:
+        flip map config.warnings (warning:
+          "${user} profile: ${warning}"
+        )
+      ));
+
+    assertions =
+      flatten (flip mapAttrsToList cfg.users (user: config:
+        flip map config.assertions (assertion:
+          {
+            inherit (assertion) assertion;
+            message = "${user} profile: ${assertion.message}";
+          }
+        )
+      ));
+
+    users.users = mkIf cfg.useUserPackages (
+      mapAttrs (username: usercfg: {
+        packages = [ usercfg.home.path ];
+      }) cfg.users
+    );
+
+    environment.pathsToLink = mkIf cfg.useUserPackages [ "/etc/profile.d" ];
+
+    system.activationScripts.postActivation.text =
+      concatStringsSep "\n" (mapAttrsToList (username: usercfg: ''
+        echo Activating home-manager configuration for ${username}
+        sudo -u ${username} -i ${pkgs.writeShellScript "activation-${username}" ''
+          ${lib.optionalString (cfg.backupFileExtension != null)
+            "export HOME_MANAGER_BACKUP_EXT=${lib.escapeShellArg cfg.backupFileExtension}"}
+          ${lib.optionalString cfg.verbose "export VERBOSE=1"}
+          exec ${usercfg.home.activationPackage}/activate
+        ''}
+      '') cfg.users);
+  };
+}