1 files changed, 91 insertions, 0 deletions
diff --git a/home-manager/modules/programs/starship.nix b/home-manager/modules/programs/starship.nix
new file mode 100644
index 00000000000..81793c7a6f6
--- /dev/null
+++ b/home-manager/modules/programs/starship.nix
@@ -0,0 +1,91 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+
+  cfg = config.programs.starship;
+
+  configFile = config:
+    pkgs.runCommand "config.toml"
+      {
+        buildInputs = [ pkgs.remarshal ];
+        preferLocalBuild = true;
+        allowSubstitutes = false;
+      }
+      ''
+        remarshal -if json -of toml \
+          < ${pkgs.writeText "config.json" (builtins.toJSON config)} \
+          > $out
+      '';
+in
+
+{
+  meta.maintainers = [ maintainers.marsam ];
+
+  options.programs.starship = {
+    enable = mkEnableOption "starship";
+
+    settings = mkOption {
+      type = types.attrs;
+      default = {};
+      description = ''
+        Configuration written to
+        <filename>~/.config/starship.toml</filename>.
+        </para><para>
+        See <link xlink:href="https://starship.rs/config/" /> for the full list
+        of options.
+      '';
+    };
+
+    enableBashIntegration = mkOption {
+      default = true;
+      type = types.bool;
+      description = ''
+        Whether to enable Bash integration.
+      '';
+    };
+
+    enableZshIntegration = mkOption {
+      default = true;
+      type = types.bool;
+      description = ''
+        Whether to enable Zsh integration.
+      '';
+    };
+
+    enableFishIntegration = mkOption {
+      default = true;
+      type = types.bool;
+      description = ''
+        Whether to enable Fish integration.
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = [ pkgs.starship ];
+
+    xdg.configFile."starship.toml" = mkIf (cfg.settings != {}) {
+      source = configFile cfg.settings;
+    };
+
+    programs.bash.initExtra = mkIf cfg.enableBashIntegration ''
+      if [[ -z $INSIDE_EMACS ]]; then
+        eval "$(${pkgs.starship}/bin/starship init bash)"
+      fi
+    '';
+
+    programs.zsh.initExtra = mkIf cfg.enableZshIntegration ''
+      if [ -z "$INSIDE_EMACS" ]; then
+        eval "$(${pkgs.starship}/bin/starship init zsh)"
+      fi
+    '';
+
+    programs.fish.shellInit = mkIf cfg.enableFishIntegration ''
+      if test -z "$INSIDE_EMACS"
+        eval (${pkgs.starship}/bin/starship init fish)
+      end
+    '';
+  };
+}