blob: 81cd2db7bd09e1c31dad1cafa593eaae82dc49d7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
{ stdenv, buildGoModule, fetchFromGitHub, nixosTests }:
buildGoModule rec {
pname = "consul";
version = "1.9.0";
rev = "v${version}";
# Note: Currently only release tags are supported, because they have the Consul UI
# vendored. See
# https://github.com/NixOS/nixpkgs/pull/48714#issuecomment-433454834
# If you want to use a non-release commit as `src`, you probably want to improve
# this derivation so that it can build the UI's JavaScript from source.
# See https://github.com/NixOS/nixpkgs/pull/49082 for something like that.
# Or, if you want to patch something that doesn't touch the UI, you may want
# to apply your changes as patches on top of a release commit.
src = fetchFromGitHub {
owner = "hashicorp";
repo = pname;
inherit rev;
sha256 = "06brmzj3h6my0pvi5n261180bfwgfn923702837jmkz7snpsdr9q";
};
passthru.tests.consul = nixosTests.consul;
# This corresponds to paths with package main - normally unneeded but consul
# has a split module structure in one repo
subPackages = ["." "connect/certgen"];
vendorSha256 = "1mc567zgymfz8iy6bg603f857c05xfna1npk2hh490dsnskkfag0";
doCheck = false;
deleteVendor = true;
preBuild = ''
buildFlagsArray+=("-ldflags"
"-X github.com/hashicorp/consul/version.GitDescribe=v${version}
-X github.com/hashicorp/consul/version.Version=${version}
-X github.com/hashicorp/consul/version.VersionPrerelease=")
'';
meta = with stdenv.lib; {
description = "Tool for service discovery, monitoring and configuration";
homepage = "https://www.consul.io/";
platforms = platforms.linux ++ platforms.darwin;
license = licenses.mpl20;
maintainers = with maintainers; [ pradeepchhetri vdemeester nh2 ];
};
}
|
