blob: 02992e7187188012eee3747fabface1938552950 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
{ stdenv
, fetchFromGitHub
, libX11
, libXt
, withGraphics ? true
}:
stdenv.mkDerivation rec {
pname = "icon-lang";
version = "unstable-2020-02-05";
src = fetchFromGitHub {
owner = "gtownsend";
repo = "icon";
rev = "829cff33de4a21546fb269de3ef5acd7b4f0c0c7";
sha256 = "1lj2f13pbaajcy4v3744bz46rghhw5sv4dwwfnzhsllbj5gnjsv2";
};
buildInputs = stdenv.lib.optionals withGraphics [ libX11 libXt ];
configurePhase =
let
target = if withGraphics then "X-Configure" else "Configure";
platform =
if stdenv.isLinux then "linux"
else if stdenv.isDarwin then "macintosh"
else if stdenv.isBSD then "bsd"
else if stdenv.isCygwin then "cygwin"
else if stdenv.isSunOS then "solaris"
else throw "unsupported system";
in
"make ${target} name=${platform}";
installPhase = ''
make Install dest=$out
rm $out/README
mkdir -p $out/share/doc
mv $out/doc $out/share/doc/icon
'';
meta = with stdenv.lib; {
description = ''A very high level general-purpose programming language'';
maintainers = with maintainers; [ vrthra yurrriq ];
platforms = with platforms; linux ++ darwin ++ freebsd ++ netbsd ++ openbsd ++ cygwin ++ illumos;
license = licenses.publicDomain;
homepage = "https://www.cs.arizona.edu/icon/";
};
}
|
