1 files changed, 41 insertions, 0 deletions
diff --git a/infra/libkookie/nixpkgs/pkgs/tools/system/monit/default.nix b/infra/libkookie/nixpkgs/pkgs/tools/system/monit/default.nix
new file mode 100644
index 000000000000..3349749d62e8
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/tools/system/monit/default.nix
@@ -0,0 +1,41 @@
+{ stdenv
+, fetchurl, bison, flex
+, zlib
+, usePAM ? stdenv.hostPlatform.isLinux, pam
+, useSSL ? true, openssl
+}:
+
+stdenv.mkDerivation rec {
+  name = "monit-5.27.1";
+
+  src = fetchurl {
+    url = "${meta.homepage}dist/${name}.tar.gz";
+    sha256 = "0lgdhif6x11fcpli0qn138rpdvrfnwmkzsy4lc9pas45c78hhx7m";
+  };
+
+  nativeBuildInputs = [ bison flex ];
+  buildInputs = [ zlib.dev ] ++
+    stdenv.lib.optionals useSSL [ openssl ] ++
+    stdenv.lib.optionals usePAM [ pam ];
+
+  configureFlags = [
+    (stdenv.lib.withFeature usePAM "pam")
+  ] ++ (if useSSL then [
+      "--with-ssl-incl-dir=${openssl.dev}/include"
+      "--with-ssl-lib-dir=${openssl.out}/lib"
+    ] else [
+      "--without-ssl"
+  ]) ++ stdenv.lib.optionals (stdenv.hostPlatform != stdenv.buildPlatform) [
+    # will need to check both these are true for musl
+    "libmonit_cv_setjmp_available=yes"
+    "libmonit_cv_vsnprintf_c99_conformant=yes"
+  ];
+
+  meta = {
+    homepage = "http://mmonit.com/monit/";
+    description = "Monitoring system";
+    license = stdenv.lib.licenses.agpl3;
+    maintainers = with stdenv.lib.maintainers; [ raskin wmertens ];
+    platforms = with stdenv.lib.platforms; linux;
+  };
+}