1 files changed, 50 insertions, 0 deletions
diff --git a/infra/libkookie/nixpkgs/pkgs/tools/security/vault/vault-bin.nix b/infra/libkookie/nixpkgs/pkgs/tools/security/vault/vault-bin.nix
new file mode 100644
index 000000000000..805afe89d31a
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/tools/security/vault/vault-bin.nix
@@ -0,0 +1,50 @@
+{ stdenv, fetchurl, unzip }:
+
+let
+  version = "1.6.0";
+
+  sources = let
+    base = "https://releases.hashicorp.com/vault/${version}";
+  in {
+    x86_64-linux = fetchurl {
+      url = "${base}/vault_${version}_linux_amd64.zip";
+      sha256 = "0fay6bw31x9kxmc52sh5qp63nfkwji74fbnlx8pj3smz3qnqw143";
+    };
+    i686-linux = fetchurl {
+      url = "${base}/vault_${version}_linux_386.zip";
+      sha256 = "0bjks9lpgl39cq55c9cyc0glhmyxzs37a2an8ynzza94gv5mgcxa";
+    };
+    x86_64-darwin = fetchurl {
+      url = "${base}/vault_${version}_darwin_amd64.zip";
+      sha256 = "0hl1k35x78y0hi3y5xjnzby1ygisqjyvdak7s61m9f363nsr1shh";
+    };
+    aarch64-linux = fetchurl {
+      url = "${base}/vault_${version}_linux_arm64.zip";
+      sha256 = "018a5i14x6phhx1axvx0bvqn4ggsimfizs48xbmykgiyfmzkrwgz";
+    };
+  };
+
+in stdenv.mkDerivation {
+  pname = "vault-bin";
+  inherit version;
+
+  src = sources.${stdenv.hostPlatform.system} or (throw "unsupported system: ${stdenv.hostPlatform.system}");
+
+  nativeBuildInputs = [ unzip ];
+
+  sourceRoot = ".";
+
+  installPhase = ''
+    mkdir -p $out/bin $out/share/bash-completion/completions
+    mv vault $out/bin
+    echo "complete -C $out/bin/vault vault" > $out/share/bash-completion/completions/vault
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = "https://www.vaultproject.io";
+    description = "A tool for managing secrets, this binary includes the UI";
+    platforms = [ "x86_64-linux" "i686-linux" "x86_64-darwin" "aarch64-linux" ];
+    license = licenses.mpl20;
+    maintainers = with maintainers; [ offline psyanticy mkaito ];
+  };
+}