1 files changed, 48 insertions, 0 deletions
diff --git a/infra/libkookie/nixpkgs/pkgs/tools/security/neopg/default.nix b/infra/libkookie/nixpkgs/pkgs/tools/security/neopg/default.nix
new file mode 100644
index 000000000000..4f4f660e20f4
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/tools/security/neopg/default.nix
@@ -0,0 +1,48 @@
+{ stdenv
+, fetchFromGitHub
+, cmake
+, sqlite
+, botan2
+, boost
+, curl
+, gettext
+, pkgconfig
+, libusb1
+, gnutls }:
+
+stdenv.mkDerivation rec {
+  pname = "neopg";
+  version = "0.0.6";
+
+  src = fetchFromGitHub {
+    owner = "das-labor";
+    repo = "neopg";
+    rev = "v${version}";
+    sha256 = "15xp5w046ix59cfrhh8ka4camr0d8qqw643g184sqrcqwpk7nbrx";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [  cmake gettext pkgconfig ];
+
+  buildInputs = [ sqlite botan2 boost curl libusb1 gnutls ];
+
+  doCheck = true;
+  checkTarget = "test";
+  dontUseCmakeBuildDir = true;
+
+  preCheck = ''
+    export LD_LIBRARY_PATH=$LD_LIBRARY_PATH''${LD_LIBRARY_PATH:+:}$(pwd)/3rdparty/googletest/googletest:$(pwd)/neopg
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = "https://neopg.io/";
+    description = "Modern replacement for GnuPG 2";
+    license = licenses.gpl3;
+    longDescription = ''
+      NeoPG starts as an opiniated fork of GnuPG 2 to clean up the code and make it easier to develop.
+      It is written in C++11.
+    '';
+    maintainers = with maintainers; [ erictapen ];
+    platforms = platforms.linux;
+  };
+}