1 files changed, 47 insertions, 0 deletions
diff --git a/infra/libkookie/nixpkgs/pkgs/tools/graphics/pfstools/default.nix b/infra/libkookie/nixpkgs/pkgs/tools/graphics/pfstools/default.nix
new file mode 100644
index 000000000000..f570251374cf
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/tools/graphics/pfstools/default.nix
@@ -0,0 +1,47 @@
+{ stdenv, mkDerivation, fetchurl, cmake, pkgconfig, darwin
+, openexr, zlib, imagemagick, libGLU, libGL, freeglut, fftwFloat
+, fftw, gsl, libexif, perl, opencv2, qtbase, netpbm
+}:
+
+mkDerivation rec {
+  pname = "pfstools";
+  version = "2.1.0";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/${pname}/${version}/${pname}-${version}.tgz";
+    sha256 = "04rlb705gmdiphcybf9dyr0d5lla2cfs3c308zz37x0vwi445six";
+  };
+
+  outputs = [ "out" "dev" "man"];
+
+  cmakeFlags = [ "-DWITH_MATLAB=false" ];
+
+  preConfigure = ''
+    rm cmake/FindNETPBM.cmake
+    echo "SET(NETPBM_LIBRARY `find ${stdenv.lib.getLib netpbm} -name "*.${stdenv.hostPlatform.extensions.sharedLibrary}*" -type f`)" >> cmake/FindNETPBM.cmake
+    echo "SET(NETPBM_LIBRARIES `find ${stdenv.lib.getLib netpbm} -name "*.${stdenv.hostPlatform.extensions.sharedLibrary}*" -type f`)" >> cmake/FindNETPBM.cmake
+    echo "SET(NETPBM_INCLUDE_DIR ${stdenv.lib.getDev netpbm}/include/netpbm)" >> cmake/FindNETPBM.cmake
+    echo "INCLUDE(FindPackageHandleStandardArgs)" >> cmake/FindNETPBM.cmake
+    echo "FIND_PACKAGE_HANDLE_STANDARD_ARGS(NETPBM DEFAULT_MSG NETPBM_LIBRARY NETPBM_INCLUDE_DIR)" >> cmake/FindNETPBM.cmake
+  '';
+
+  nativeBuildInputs = [ cmake pkgconfig ];
+  buildInputs = [
+    openexr zlib imagemagick fftwFloat
+    fftw gsl libexif perl opencv2 qtbase netpbm
+  ] ++ (if stdenv.isDarwin then (with darwin.apple_sdk.frameworks; [
+    OpenGL GLUT
+  ]) else [
+    libGLU libGL freeglut
+  ]);
+
+  patches = [ ./threads.patch ./pfstools.patch ./pfsalign.patch ];
+
+  meta = with stdenv.lib; {
+    homepage = "http://pfstools.sourceforge.net/";
+    description = "Toolkit for manipulation of HDR images";
+    platforms = platforms.linux;
+    license = licenses.lgpl2;
+    maintainers = [ maintainers.juliendehos ];
+  };
+}