1 files changed, 49 insertions, 0 deletions
diff --git a/infra/libkookie/nixpkgs/pkgs/servers/monitoring/grafana/default.nix b/infra/libkookie/nixpkgs/pkgs/servers/monitoring/grafana/default.nix
new file mode 100644
index 000000000000..ccd7428eefcd
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/servers/monitoring/grafana/default.nix
@@ -0,0 +1,49 @@
+{ lib, buildGoModule, fetchurl, fetchFromGitHub, nixosTests }:
+
+buildGoModule rec {
+  pname = "grafana";
+  version = "7.3.4";
+
+  excludedPackages = [ "release_publisher" ];
+
+  src = fetchFromGitHub {
+    rev = "v${version}";
+    owner = "grafana";
+    repo = "grafana";
+    sha256 = "0vav3zhn4yw87z8xlcljs62xx4v3mxxvy0kgjh7w4njyqq1j3ayi";
+  };
+
+  srcStatic = fetchurl {
+    url = "https://dl.grafana.com/oss/release/grafana-${version}.linux-amd64.tar.gz";
+    sha256 = "1fmfscfbdg2wdzf5fbad83pln4azy2y3fcghcanafkvqr2vv4hwk";
+  };
+
+  vendorSha256 = "0rn1zqczqa44k6g8rm9xdrd6hw5rbbvihcbzcdx758gv2lpbikxq";
+
+  postPatch = ''
+    substituteInPlace pkg/cmd/grafana-server/main.go \
+      --replace 'var version = "5.0.0"'  'var version = "${version}"'
+  '';
+
+  # fixes build failure with go 1.15:
+  # main module (github.com/grafana/grafana) does not contain package github.com/grafana/grafana/scripts/go
+  preBuild = ''
+    rm -rf scripts/go
+  '';
+
+  postInstall = ''
+    tar -xvf $srcStatic
+    mkdir -p $out/share/grafana
+    mv grafana-*/{public,conf,tools} $out/share/grafana/
+  '';
+
+  passthru.tests = { inherit (nixosTests) grafana; };
+
+  meta = with lib; {
+    description = "Gorgeous metric viz, dashboards & editors for Graphite, InfluxDB & OpenTSDB";
+    license = licenses.asl20;
+    homepage = "https://grafana.com";
+    maintainers = with maintainers; [ offline fpletz willibutz globin ma27 Frostman ];
+    platforms = platforms.linux;
+  };
+}