1 files changed, 41 insertions, 0 deletions
diff --git a/infra/libkookie/nixpkgs/pkgs/games/multimc/default.nix b/infra/libkookie/nixpkgs/pkgs/games/multimc/default.nix
new file mode 100644
index 000000000000..c114afe9a8e3
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/games/multimc/default.nix
@@ -0,0 +1,41 @@
+{ stdenv, mkDerivation, fetchFromGitHub, cmake, jdk8, zlib, file, makeWrapper, xorg, libpulseaudio, qtbase }:
+
+let
+  jdk = jdk8;
+  libpath = with xorg; stdenv.lib.makeLibraryPath [ libX11 libXext libXcursor libXrandr libXxf86vm libpulseaudio ];
+in mkDerivation rec {
+  pname = "multimc";
+  version = "0.6.11";
+  src = fetchFromGitHub {
+    owner = "MultiMC";
+    repo = "MultiMC5";
+    rev = version;
+    sha256 = "1jkbmb4sgfk8d93f5l1vd9pkpvhq9sxacc61w0rvf5xmz0wnszmz";
+    fetchSubmodules = true;
+  };
+  nativeBuildInputs = [ cmake file makeWrapper ];
+  buildInputs = [ qtbase jdk zlib ];
+
+  enableParallelBuilding = true;
+
+  cmakeFlags = [ "-DMultiMC_LAYOUT=lin-system" ];
+
+  postInstall = ''
+    install -Dm644 ../application/resources/multimc/scalable/multimc.svg $out/share/pixmaps/multimc.svg
+    install -Dm755 ../application/package/linux/multimc.desktop $out/share/applications/multimc.desktop
+
+    # xorg.xrandr needed for LWJGL [2.9.2, 3) https://github.com/LWJGL/lwjgl/issues/128
+    wrapProgram $out/bin/multimc --set GAME_LIBRARY_PATH /run/opengl-driver/lib:${libpath} --prefix PATH : ${jdk}/bin/:${xorg.xrandr}/bin/
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = "https://multimc.org/";
+    description = "A free, open source launcher for Minecraft";
+    longDescription = ''
+      Allows you to have multiple, separate instances of Minecraft (each with their own mods, texture packs, saves, etc) and helps you manage them and their associated options with a simple interface.
+    '';
+    platforms = platforms.linux;
+    license = licenses.lgpl21Plus;
+    maintainers = [ maintainers.cleverca22 ];
+  };
+}