1 files changed, 49 insertions, 0 deletions
diff --git a/infra/libkookie/nixpkgs/pkgs/development/python-modules/pygame/default.nix b/infra/libkookie/nixpkgs/pkgs/development/python-modules/pygame/default.nix
new file mode 100644
index 000000000000..81c4d4a4b9c1
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/development/python-modules/pygame/default.nix
@@ -0,0 +1,49 @@
+{ lib, fetchPypi, buildPythonPackage, python, pkg-config, libX11
+, SDL, SDL_image, SDL_mixer, SDL_ttf, libpng, libjpeg, portmidi, freetype
+}:
+
+buildPythonPackage rec {
+  pname = "pygame";
+  version = "2.0.0";
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "63b038da116a643046181b02173fd894d87d2f85ecfd6aa7d5ece73c6ef501e9";
+  };
+
+  nativeBuildInputs = [
+    pkg-config SDL
+  ];
+
+  buildInputs = [
+    SDL SDL_image SDL_mixer SDL_ttf libpng libjpeg
+    portmidi libX11 freetype
+  ];
+
+  # Tests fail because of no audio device and display.
+  doCheck = false;
+
+  preConfigure = ''
+    sed \
+      -e "s/origincdirs = .*/origincdirs = []/" \
+      -e "s/origlibdirs = .*/origlibdirs = []/" \
+      -e "/'\/lib\/i386-linux-gnu', '\/lib\/x86_64-linux-gnu']/d" \
+      -e "/\/include\/smpeg/d" \
+      -i buildconfig/config_unix.py
+    ${lib.concatMapStrings (dep: ''
+      sed \
+        -e "/origincdirs =/a\        origincdirs += ['${lib.getDev dep}/include']" \
+        -e "/origlibdirs =/a\        origlibdirs += ['${lib.getLib dep}/lib']" \
+        -i buildconfig/config_unix.py
+      '') buildInputs
+    }
+    LOCALBASE=/ ${python.interpreter} buildconfig/config.py
+  '';
+
+  meta = with lib; {
+    description = "Python library for games";
+    homepage = "http://www.pygame.org/";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+  };
+}