1 files changed, 66 insertions, 0 deletions
diff --git a/infra/libkookie/nixpkgs/pkgs/development/libraries/rocksdb/default.nix b/infra/libkookie/nixpkgs/pkgs/development/libraries/rocksdb/default.nix
new file mode 100644
index 000000000000..f17a114216bd
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/development/libraries/rocksdb/default.nix
@@ -0,0 +1,66 @@
+{ stdenv
+, fetchFromGitHub
+, fetchpatch
+, cmake
+, ninja
+, bzip2
+, lz4
+, snappy
+, zlib
+, zstd
+, enableJemalloc ? false, jemalloc
+, enableLite ? false
+, enableShared ? true
+}:
+
+stdenv.mkDerivation rec {
+  pname = "rocksdb";
+  version = "6.14.6";
+
+  src = fetchFromGitHub {
+    owner = "facebook";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "0cp0jgzwkwamykgnmsg0zvzakq58f1ihs7lslnn4nh4p9gm75rq5";
+  };
+
+  nativeBuildInputs = [ cmake ninja ];
+
+  propagatedBuildInputs = [ bzip2 lz4 snappy zlib zstd ];
+
+  buildInputs = stdenv.lib.optional enableJemalloc jemalloc;
+
+  NIX_CFLAGS_COMPILE = stdenv.lib.optionalString stdenv.cc.isGNU "-Wno-error=deprecated-copy -Wno-error=pessimizing-move";
+
+  cmakeFlags = [
+    "-DPORTABLE=1"
+    "-DWITH_JEMALLOC=${if enableJemalloc then "1" else "0"}"
+    "-DWITH_JNI=0"
+    "-DWITH_BENCHMARK_TOOLS=0"
+    "-DWITH_TESTS=1"
+    "-DWITH_TOOLS=0"
+    "-DWITH_BZ2=1"
+    "-DWITH_LZ4=1"
+    "-DWITH_SNAPPY=1"
+    "-DWITH_ZLIB=1"
+    "-DWITH_ZSTD=1"
+    "-DWITH_GFLAGS=0"
+    "-DUSE_RTTI=1"
+    "-DROCKSDB_INSTALL_ON_WINDOWS=YES" # harmless elsewhere
+    (stdenv.lib.optional
+        (stdenv.hostPlatform.isx86 && stdenv.hostPlatform.isLinux)
+        "-DFORCE_SSE42=1")
+    (stdenv.lib.optional enableLite "-DROCKSDB_LITE=1")
+    "-DFAIL_ON_WARNINGS=${if stdenv.hostPlatform.isMinGW then "NO" else "YES"}"
+  ] ++ stdenv.lib.optional (!enableShared) "-DROCKSDB_BUILD_SHARED=0";
+
+  # otherwise "cc1: error: -Wformat-security ignored without -Wformat [-Werror=format-security]"
+  hardeningDisable = stdenv.lib.optional stdenv.hostPlatform.isWindows "format";
+
+  meta = with stdenv.lib; {
+    homepage = "https://rocksdb.org";
+    description = "A library that provides an embeddable, persistent key-value store for fast storage";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ adev magenbluten ];
+  };
+}