1 files changed, 65 insertions, 0 deletions
diff --git a/infra/libkookie/nixpkgs/pkgs/applications/window-managers/picom/default.nix b/infra/libkookie/nixpkgs/pkgs/applications/window-managers/picom/default.nix
new file mode 100644
index 000000000000..064e555f3a5b
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/applications/window-managers/picom/default.nix
@@ -0,0 +1,65 @@
+{ stdenv, lib, fetchFromGitHub, pkgconfig, uthash, asciidoc, docbook_xml_dtd_45
+, docbook_xsl, libxslt, libxml2, makeWrapper, meson, ninja
+, xorgproto, libxcb ,xcbutilrenderutil, xcbutilimage, pixman, libev
+, dbus, libconfig, libdrm, libGL, pcre, libX11
+, libXinerama, libXext, xwininfo, libxdg_basedir }:
+
+stdenv.mkDerivation rec {
+  pname = "picom";
+  version = "8.2";
+
+  src = fetchFromGitHub {
+    owner  = "yshui";
+    repo   = "picom";
+    rev    = "v${version}";
+    sha256 = "0gjksayz2xpmgglvw17ppsan2imrd1fijs579kbf27xwp503xgfl";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [
+    meson ninja
+    pkgconfig
+    uthash
+    asciidoc
+    docbook_xml_dtd_45
+    docbook_xsl
+    makeWrapper
+  ];
+
+  buildInputs = [
+    dbus libX11 libXext
+    xorgproto
+    libXinerama libdrm pcre libxml2 libxslt libconfig libGL
+    libxcb xcbutilrenderutil xcbutilimage
+    pixman libev
+    libxdg_basedir
+  ];
+
+  NIX_CFLAGS_COMPILE = "-fno-strict-aliasing";
+
+  mesonFlags = [
+    "-Dbuild_docs=true"
+  ];
+
+  installFlags = [ "PREFIX=$(out)" ];
+
+  postInstall = ''
+    wrapProgram $out/bin/picom-trans \
+      --prefix PATH : ${lib.makeBinPath [ xwininfo ]}
+  '';
+
+  meta = with lib; {
+    description = "A fork of XCompMgr, a sample compositing manager for X servers";
+    longDescription = ''
+      A fork of XCompMgr, which is a sample compositing manager for X
+      servers supporting the XFIXES, DAMAGE, RENDER, and COMPOSITE
+      extensions. It enables basic eye-candy effects. This fork adds
+      additional features, such as additional effects, and a fork at a
+      well-defined and proper place.
+    '';
+    license = licenses.mit;
+    homepage = "https://github.com/yshui/picom";
+    maintainers = with maintainers; [ ertes enzime twey ];
+    platforms = platforms.linux;
+  };
+}