abbaye-des-morts: init at 2.0.1

1 files changed, 35 insertions, 0 deletions

diff --git a/pkgs/games/abbaye-des-morts/default.nix b/pkgs/games/abbaye-des-morts/default.nix
new file mode 100644
index 000000000000..103b67e99edf
--- /dev/null
+++ b/pkgs/games/abbaye-des-morts/default.nix
@@ -0,0 +1,35 @@
+{ stdenv, fetchFromGitHub, SDL2, SDL2_image, SDL2_mixer }:
+
+stdenv.mkDerivation rec {
+  pname = "abbaye-des-morts";
+  version = "2.0.1";
+
+  src = fetchFromGitHub {
+    owner = "nevat";
+    repo = "abbayedesmorts-gpl";
+    rev = "v${version}";
+    sha256 = "1pwqf7r9bqb2p3xrw9i7y8pgr1401fy3mnnqpb1qkhmdl3gqi9hb";
+  };
+
+  buildInputs = [ SDL2 SDL2_image SDL2_mixer ];
+
+  makeFlags = [ "PREFIX=$(out)" "DESTDIR=" ];
+
+  preBuild = stdenv.lib.optionalString stdenv.cc.isClang
+    ''
+      substituteInPlace Makefile \
+        --replace -fpredictive-commoning ""
+    '';
+
+  preInstall = ''
+    mkdir -p $out/bin
+    mkdir -p $out/share/applications
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = "https://locomalito.com/abbaye_des_morts.php";
+    description = "A retro arcade video game";
+    license = licenses.gpl3;
+    maintainers = [ maintainers.marius851000 ];
+  };
+}