Add 'infra/libkookie/' from commit 'd661aa56a8843e991261510c1bb28fdc2f6975ae'

git-subtree-dir: infra/libkookie
git-subtree-mainline: 49f735974dd103039ddc4cb576bb76555164a9e7
git-subtree-split: d661aa56a8843e991261510c1bb28fdc2f6975ae

1 files changed, 41 insertions, 0 deletions

diff --git a/infra/libkookie/nixpkgs/pkgs/tools/backup/restic/default.nix b/infra/libkookie/nixpkgs/pkgs/tools/backup/restic/default.nix
new file mode 100644
index 000000000000..33cac4ad229b
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/tools/backup/restic/default.nix
@@ -0,0 +1,41 @@
+{ stdenv, lib, buildGoPackage, fetchFromGitHub, installShellFiles, makeWrapper
+, nixosTests, rclone }:
+
+buildGoPackage rec {
+  pname = "restic";
+  version = "0.9.6";
+
+  goPackagePath = "github.com/restic/restic";
+
+  src = fetchFromGitHub {
+    owner = "restic";
+    repo = "restic";
+    rev = "v${version}";
+    sha256 = "0lydll93n1lcn1fl669b9cikmzz9d6vfpc8ky3ng5fi8kj3v1dz7";
+  };
+
+  subPackages = [ "cmd/restic" ];
+
+  nativeBuildInputs = [ installShellFiles makeWrapper ];
+
+  passthru.tests.restic = nixosTests.restic;
+
+  postInstall = ''
+    wrapProgram $out/bin/restic --prefix PATH : '${rclone}/bin'
+  '' + lib.optionalString (stdenv.hostPlatform == stdenv.buildPlatform) ''
+    $out/bin/restic generate \
+      --bash-completion restic.bash \
+      --zsh-completion restic.zsh \
+      --man .
+    installShellCompletion restic.{bash,zsh}
+    installManPage *.1
+  '';
+
+  meta = with lib; {
+    homepage = "https://restic.net";
+    description = "A backup program that is fast, efficient and secure";
+    platforms = platforms.linux ++ platforms.darwin;
+    license = licenses.bsd2;
+    maintainers = [ maintainers.mbrgm ];
+  };
+}