Add 'infra/libkookie/nixpkgs/' from commit 'e9158eca70ae59e73fae23be5d13d3fa0cfc78b4'

git-subtree-dir: infra/libkookie/nixpkgs
git-subtree-mainline: 2e04b35e5ac3a9123cafffbc84494fa4d389cca0
git-subtree-split: e9158eca70ae59e73fae23be5d13d3fa0cfc78b4

2 files changed, 79 insertions, 0 deletions

diff --git a/infra/libkookie/nixpkgs/pkgs/servers/nextcloud/default.nix b/infra/libkookie/nixpkgs/pkgs/servers/nextcloud/default.nix
new file mode 100644
index 000000000000..6b1e7de83245
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/servers/nextcloud/default.nix
@@ -0,0 +1,57 @@
+{ stdenv, fetchurl, nixosTests }:
+
+let
+  generic = { version, sha256, insecure ? false }: stdenv.mkDerivation rec {
+    pname = "nextcloud";
+    inherit version;
+
+    src = fetchurl {
+      url = "https://download.nextcloud.com/server/releases/${pname}-${version}.tar.bz2";
+      inherit sha256;
+    };
+
+    passthru.tests = nixosTests.nextcloud;
+
+    installPhase = ''
+      mkdir -p $out/
+      cp -R . $out/
+    '';
+
+    meta = with stdenv.lib; {
+      description = "Sharing solution for files, calendars, contacts and more";
+      homepage = "https://nextcloud.com";
+      maintainers = with maintainers; [ schneefux bachp globin fpletz ma27 ];
+      license = licenses.agpl3Plus;
+      platforms = with platforms; unix;
+      knownVulnerabilities = optional insecure "Nextcloud version ${version} is EOL";
+    };
+  };
+in {
+  nextcloud17 = throw ''
+    Nextcloud v17 has been removed from `nixpkgs` as the support for it will be dropped
+    by upstream within the lifetime of NixOS 20.09[1]. Please upgrade to Nextcloud v18 by
+    declaring
+
+        services.nextcloud.package = pkgs.nextcloud18;
+
+    in your NixOS config.
+
+    [1] https://docs.nextcloud.com/server/18/admin_manual/release_schedule.html
+  '';
+
+  nextcloud18 = generic {
+    version = "18.0.10";
+    sha256 = "0kv9mdn36shr98kh27969b8xs7pgczbyjklrfskxy9mph7bbzir6";
+    insecure = true;
+  };
+
+  nextcloud19 = generic {
+    version = "19.0.4";
+    sha256 = "0y5fccn61qf9fxjjpqdvhmxr9w5n4dgl1d7wcl2dzjv4bmqi2ms6";
+  };
+
+  nextcloud20 = generic {
+    version = "20.0.1";
+    sha256 = "1z1fzz1i41k4dhdhi005l3gzkvnmmgqqz3rdr374cvk73q7bbiln";
+  };
+}
diff --git a/infra/libkookie/nixpkgs/pkgs/servers/nextcloud/news-updater.nix b/infra/libkookie/nixpkgs/pkgs/servers/nextcloud/news-updater.nix
new file mode 100644
index 000000000000..dd7e8e4879c5
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/servers/nextcloud/news-updater.nix
@@ -0,0 +1,22 @@
+{ stdenv, fetchurl, python3Packages, php }:
+
+python3Packages.buildPythonApplication rec {
+  name = "nextcloud-news-updater-${version}";
+  version = "10.0.1";
+
+  src = fetchurl {
+    url = "mirror://pypi/n/nextcloud_news_updater/nextcloud_news_updater-${version}.tar.gz";
+    sha256 = "14jj3w417wfsm1ki34d980b0s6vfn8i29g4c66qb2fizdq1d0z6q";
+  };
+
+  doCheck = false;
+
+  propagatedBuildInputs = [ php ];
+
+  meta = {
+    description = "Fast parallel feed updater for the Nextcloud news app";
+    homepage = "https://github.com/nextcloud/news-updater";
+    license = stdenv.lib.licenses.gpl3;
+    maintainers = with stdenv.lib.maintainers; [ schneefux ];
+  };
+}