Add 'infra/libkookie/' from commit 'd661aa56a8843e991261510c1bb28fdc2f6975ae'

git-subtree-dir: infra/libkookie
git-subtree-mainline: 49f735974dd103039ddc4cb576bb76555164a9e7
git-subtree-split: d661aa56a8843e991261510c1bb28fdc2f6975ae

1 files changed, 49 insertions, 0 deletions

diff --git a/infra/libkookie/nixpkgs/pkgs/servers/monitoring/prometheus/pushgateway.nix b/infra/libkookie/nixpkgs/pkgs/servers/monitoring/prometheus/pushgateway.nix
new file mode 100644
index 000000000000..1425fccdca4b
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/servers/monitoring/prometheus/pushgateway.nix
@@ -0,0 +1,49 @@
+{ stdenv, go, buildGoPackage, fetchFromGitHub }:
+
+buildGoPackage rec {
+  pname = "pushgateway";
+  version = "1.2.0";
+  rev = "v${version}";
+
+  goPackagePath = "github.com/prometheus/pushgateway";
+
+  src = fetchFromGitHub {
+    inherit rev;
+    owner = "prometheus";
+    repo = "pushgateway";
+    sha256 = "0q57pvdfapi1xx8mw7ykvxs64alypyqbxwvrqjcrgv2jidbcd1mm";
+  };
+
+  buildUser = "nix@nixpkgs";
+  buildDate = "19700101-00:00:00";
+
+  buildFlagsArray = ''
+    -ldflags=
+        -X github.com/prometheus/pushgateway/vendor/github.com/prometheus/common/version.Version=${version}
+        -X github.com/prometheus/pushgateway/vendor/github.com/prometheus/common/version.Revision=${rev}
+        -X github.com/prometheus/pushgateway/vendor/github.com/prometheus/common/version.Branch=${rev}
+        -X github.com/prometheus/pushgateway/vendor/github.com/prometheus/common/version.BuildUser=${buildUser}
+        -X github.com/prometheus/pushgateway/vendor/github.com/prometheus/common/version.BuildDate=${buildDate}
+        -X main.goVersion=${stdenv.lib.getVersion go}
+  '';
+
+  doInstallCheck = true;
+  installCheckPhase = ''
+    export PATH=$PATH:$out/bin
+
+    pushgateway --help
+
+    # Make sure our -X options were included in the build
+    for s in ${version} ${rev} ${buildUser} ${buildDate}; do
+      pushgateway --version 2>&1 | fgrep -q -- "$s" || { echo "pushgateway --version output missing $s"; exit 1; }
+    done
+  '';
+
+  meta = with stdenv.lib; {
+    description = "Allows ephemeral and batch jobs to expose metrics to Prometheus";
+    homepage = "https://github.com/prometheus/pushgateway";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ benley fpletz ];
+    platforms = platforms.unix;
+  };
+}