Add 'infra/libkookie/' from commit 'd661aa56a8843e991261510c1bb28fdc2f6975ae'

git-subtree-dir: infra/libkookie
git-subtree-mainline: 49f735974dd103039ddc4cb576bb76555164a9e7
git-subtree-split: d661aa56a8843e991261510c1bb28fdc2f6975ae

2 files changed, 78 insertions, 0 deletions

diff --git a/infra/libkookie/nixpkgs/pkgs/games/sgt-puzzles/default.nix b/infra/libkookie/nixpkgs/pkgs/games/sgt-puzzles/default.nix
new file mode 100644
index 000000000000..c17439b5e3e8
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/games/sgt-puzzles/default.nix
@@ -0,0 +1,73 @@
+{ stdenv, fetchurl, desktop-file-utils
+, gtk3, libX11
+, makeWrapper, pkgconfig, perl, autoreconfHook, wrapGAppsHook
+}:
+
+stdenv.mkDerivation rec {
+  name = "sgt-puzzles-r${version}";
+  version = "20191114.1c0c49d";
+
+  src = fetchurl {
+    url = "http://www.chiark.greenend.org.uk/~sgtatham/puzzles/puzzles-${version}.tar.gz";
+    sha256 = "01fi2f3w71bfbgcfr6gxdp5a9cxh4dshbflv83q2j5rxxs2ll870";
+  };
+
+  sgt-puzzles-menu = fetchurl {
+    url = "https://raw.githubusercontent.com/Oleh-Kravchenko/portage/master/games-puzzle/sgt-puzzles/files/sgt-puzzles.menu";
+    sha256 = "088w0x9g3j8pn725ix8ny8knhdsfgjr3hpswsh9fvfkz5vlg2xkm";
+  };
+
+  nativeBuildInputs = [ autoreconfHook desktop-file-utils makeWrapper
+    pkgconfig perl wrapGAppsHook ];
+
+  buildInputs = [ gtk3 libX11 ];
+
+  makeFlags = [ "prefix=$(out)" "gamesdir=$(out)/bin"];
+
+  preInstall = ''
+    mkdir -p "$out"/{bin,share/doc/sgtpuzzles}
+    cp gamedesc.txt LICENCE README "$out/share/doc/sgtpuzzles"
+  '';
+
+  postInstall = ''
+    for i in  $(basename -s $out/bin/*); do
+
+      ln -s $out/bin/$i $out/bin/sgt-puzzle-$i
+      install -Dm644 icons/$i-48d24.png -t $out/share/icons/hicolor/48x48/apps/
+
+      # Generate/validate/install .desktop files.
+      echo "[Desktop Entry]" > $i.desktop
+      desktop-file-install --dir $out/share/applications \
+        --set-key Type --set-value Application \
+        --set-key Exec --set-value $i \
+        --set-key Name --set-value $i \
+        --set-key Comment --set-value "${meta.description}" \
+        --set-key Categories --set-value "Game;LogicGame;X-sgt-puzzles;" \
+        --set-key Icon --set-value $out/share/icons/hicolor/48x48/apps/$i-48d24 \
+        $i.desktop
+    done
+
+    echo "[Desktop Entry]" > sgt-puzzles.directory
+    desktop-file-install --dir $out/share/desktop-directories \
+      --set-key Type --set-value Directory \
+      --set-key Name --set-value Puzzles \
+      --set-key Icon --set-value $out/share/icons/hicolor/48x48/apps/sgt-puzzles_map \
+      sgt-puzzles.directory
+
+    install -Dm644 ${sgt-puzzles-menu} -t $out/etc/xdg/menus/applications-merged/
+  '';
+
+  preConfigure = ''
+    perl mkfiles.pl
+    export NIX_LDFLAGS="$NIX_LDFLAGS -lX11"
+    export NIX_CFLAGS_COMPILE="$NIX_CFLAGS_COMPILE -Wno-error"
+    cp Makefile.gtk Makefile
+  '';
+  meta = with stdenv.lib; {
+    description = "Simon Tatham's portable puzzle collection";
+    license = licenses.mit;
+    maintainers = [ maintainers.raskin maintainers.genesis ];
+    platforms = platforms.linux;
+    homepage = "https://www.chiark.greenend.org.uk/~sgtatham/puzzles/";
+  };
+}
diff --git a/infra/libkookie/nixpkgs/pkgs/games/sgt-puzzles/default.upstream b/infra/libkookie/nixpkgs/pkgs/games/sgt-puzzles/default.upstream
new file mode 100644
index 000000000000..b6d048b68ae9
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/games/sgt-puzzles/default.upstream
@@ -0,0 +1,5 @@
+minimize_overwrite
+url http://www.chiark.greenend.org.uk/~sgtatham/puzzles/puzzles.tar.gz
+redirect
+NEED_TO_CHOOSE_URL=
+version '.*[-_.]([0-9]{8}[.][^.]+)[.]tar[.].*' '\1'