Add 'infra/libkookie/' from commit 'd661aa56a8843e991261510c1bb28fdc2f6975ae'

git-subtree-dir: infra/libkookie
git-subtree-mainline: 49f735974dd103039ddc4cb576bb76555164a9e7
git-subtree-split: d661aa56a8843e991261510c1bb28fdc2f6975ae

2 files changed, 140 insertions, 0 deletions

diff --git a/infra/libkookie/nixpkgs/pkgs/development/libraries/zeroc-ice/3.6.nix b/infra/libkookie/nixpkgs/pkgs/development/libraries/zeroc-ice/3.6.nix
new file mode 100644
index 000000000000..7f6c7323fff3
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/development/libraries/zeroc-ice/3.6.nix
@@ -0,0 +1,67 @@
+{ stdenv, lib, fetchFromGitHub, fetchpatch, mcpp, bzip2, expat, openssl, db5
+, darwin, libiconv, Security
+, cpp11 ? false
+}:
+
+stdenv.mkDerivation rec {
+  pname = "zeroc-ice";
+  version = "3.6.3";
+
+  src = fetchFromGitHub {
+    owner = "zeroc-ice";
+    repo = "ice";
+    rev = "v${version}";
+    sha256 = "05xympbns32aalgcfcpxwfd7bvg343f16xpg6jv5s335ski3cjy2";
+  };
+
+  buildInputs = [ mcpp bzip2 expat openssl db5 ]
+    ++ lib.optionals stdenv.isDarwin [ darwin.cctools libiconv Security ];
+
+  postUnpack = ''
+    sourceRoot=$sourceRoot/cpp
+  '';
+
+  prePatch = lib.optional stdenv.isDarwin ''
+    substituteInPlace config/Make.rules.Darwin \
+        --replace xcrun ""
+  '';
+
+  patches = [
+    # Fixes compilation issues with GCC 8 using one of the patches
+    # provided in https://github.com/zeroc-ice/ice/issues/82
+    ( fetchpatch {
+      url = "https://github.com/zeroc-ice/ice/commit/a6a4981616b669432ff7b588179d6e93694d9e3f.patch";
+      sha256 = "17j5r7gsa3izrm7zln4mrp7l16h532gvmpas0kzglybicbiz7d56";
+      stripLen = 1;
+    })
+  ];
+
+  preBuild = ''
+    makeFlagsArray+=(
+      "prefix=$out"
+      "OPTIMIZE=yes"
+      "USR_DIR_INSTALL=yes"
+      "CONFIGS=${if cpp11 then "cpp11-shared" else "shared"}"
+      "SKIP=slice2py" # provided by a separate package
+    )
+  '';
+
+  # cannot find -lIceXML (linking bin/transformdb)
+  enableParallelBuilding = false;
+
+  outputs = [ "out" "bin" "dev" ];
+
+  postInstall = ''
+    mkdir -p $bin $dev/share
+    mv $out/bin $bin
+    mv $out/share/Ice-* $dev/share/ice
+    rm -rf $out/share/slice
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = "http://www.zeroc.com/ice.html";
+    description = "The internet communications engine";
+    license = licenses.gpl2;
+    platforms = platforms.unix;
+  };
+}
diff --git a/infra/libkookie/nixpkgs/pkgs/development/libraries/zeroc-ice/default.nix b/infra/libkookie/nixpkgs/pkgs/development/libraries/zeroc-ice/default.nix
new file mode 100644
index 000000000000..2fb36c0aea58
--- /dev/null
+++ b/infra/libkookie/nixpkgs/pkgs/development/libraries/zeroc-ice/default.nix
@@ -0,0 +1,73 @@
+{ stdenv, lib, fetchFromGitHub, bzip2, expat, openssl, lmdb
+, darwin, libiconv, Security
+, cpp11 ? false
+}:
+
+let
+  zeroc_mcpp = stdenv.mkDerivation rec {
+    pname = "zeroc-mcpp";
+    version = "2.7.2.14";
+
+    src = fetchFromGitHub {
+      owner = "zeroc-ice";
+      repo = "mcpp";
+      rev = "v${version}";
+      sha256 = "1psryc2ql1cp91xd3f8jz84mdaqvwzkdq2pr96nwn03ds4cd88wh";
+    };
+
+    configureFlags = [ "--enable-mcpplib" ];
+    installFlags = [ "PREFIX=$(out)" ];
+  };
+
+in stdenv.mkDerivation rec {
+  pname = "zeroc-ice";
+  version = "3.7.2";
+
+  src = fetchFromGitHub {
+    owner = "zeroc-ice";
+    repo = "ice";
+    rev = "v${version}";
+    sha256 = "0m9lh79dfpcwcp2jhmj0wqdcsw3rl633x2hzfw9n2i34jjv64fvg";
+  };
+
+  buildInputs = [ zeroc_mcpp bzip2 expat openssl lmdb ]
+    ++ lib.optionals stdenv.isDarwin [ darwin.cctools libiconv Security ];
+
+  NIX_CFLAGS_COMPILE = "-Wno-error=class-memaccess -Wno-error=deprecated-copy";
+
+  prePatch = lib.optional stdenv.isDarwin ''
+    substituteInPlace Make.rules.Darwin \
+        --replace xcrun ""
+  '';
+
+  preBuild = ''
+    makeFlagsArray+=(
+      "prefix=$out"
+      "OPTIMIZE=yes"
+      "USR_DIR_INSTALL=yes"
+      "LANGUAGES=cpp"
+      "CONFIGS=${if cpp11 then "cpp11-shared" else "shared"}"
+      "SKIP=slice2py" # provided by a separate package
+    )
+  '';
+
+  buildFlags = [ "srcs" ]; # no tests; they require network
+
+  enableParallelBuilding = true;
+
+  outputs = [ "out" "bin" "dev" ];
+
+  postInstall = ''
+    mkdir -p $bin $dev/share
+    mv $out/bin $bin
+    mv $out/share/ice $dev/share
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = "https://www.zeroc.com/ice.html";
+    description = "The internet communications engine";
+    license = licenses.gpl2;
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ abbradar ];
+  };
+}